Плъгин, който засича играчи от другия отбор

[Tornado_SW]

Здравейте, търся прост плъгин, който при натискане на бутона "R" да засича колко играчи от другия отбор има в област от 200 метра максимум примерно. И да го изписва в чата само на играчът натиснал бутона.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <engine>
#include <fakemeta>

#if !defined MAX_PLAYERS
	const MAX_PLAYERS = 32
#endif

const Float:SEARCH_RADIUS = 1000.0

public plugin_init()
{
	register_plugin("Detect Enemies in Radius", "1.0", "OciXCrom")
	register_forward(FM_CmdStart, "OnCmdStart")
}

public OnCmdStart(id, iHandle, iSeed)
{
	if(is_user_alive(id))
	{
		new iButton = get_uc(iHandle, UC_Buttons)

		if(iButton & IN_RELOAD)
		{
			iButton &= ~IN_RELOAD
			set_uc(iHandle, UC_Buttons, iButton)

			new iPlayers[MAX_PLAYERS], iCount, iPnum = find_sphere_class(id, "player", SEARCH_RADIUS, iPlayers, sizeof(iPlayers))

			if(!iPnum)
			{
				return
			}

			for(new CsTeams:iTeam = cs_get_user_team(id), i; i < iPnum; i++)
			{
				if(cs_get_user_team(iPlayers[i]) != iTeam)
				{
					iCount++
				}
			}

			CC_SendMessage(id, "&x04* &x01Enemies near you: &x04%i", iCount)
		}
	}
}

[Tornado_SW]

Златен си, мерси!