Заявка за плъгин изиграно време

[cgozzie]

Може ли да направите плъгин като под радара да му изписва колко изиграно време има до момента играча в сървъра / Да го изписва така

Изиграно време: 1:23:05 / примерно и времето да му се запазва///

[TheRedShoko]

Цвят на HUD-a?

[cgozzie]

Изиграно време в /бяло а таймера в зелено

[TheRedShoko]

Няма как да са в различни цветове.

[cgozzie]

Добре ти реши как ще изглежда най добре

[TheRedShoko]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <engine>
#include <fvault>

new const szFVaultName[] = "played_time";
new const szHudClass[] = "hud_think_class_ptime";

new g_iPlayedSeconds[33];
new g_iMaxPlayers, g_iSyncChannel;

public plugin_init()
{
    register_plugin("Played time", "1.0", "AMXX-BG.info");
    
    new iEnt = create_entity("info_target");
    
    if (iEnt)
    {
        register_think(szHudClass, "FwHudThink");
        
        entity_set_string(iEnt, EV_SZ_classname, szHudClass);
        entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 0.1);
    }
    
    g_iMaxPlayers = get_maxplayers();
    g_iSyncChannel = CreateHudSyncObj();
}

public FwHudThink(iEnt)
{
    if (!is_valid_ent(iEnt)) return;
    
    new szTimeFormat[32];
    
    for (new i = 1; i <= g_iMaxPlayers; i++)
    {
        if (!is_user_connected(i)) continue;
        
        formatex(szTimeFormat, charsmax(szTimeFormat), "");
        
        g_iPlayedSeconds[i]++;
        
        GetTimeFormat(g_iPlayedSeconds[i], szTimeFormat);
        
        set_hudmessage(0, 150, 200, 0.01, 0.2, 0, .channel=-1);
        ShowSyncHudMsg(i, g_iSyncChannel, "Played time: %s", szTimeFormat);
    }
    
    entity_set_float(iEnt, EV_FL_nextthink, get_gametime() + 1.0);
}

public client_putinserver(id)
{
    new szName[32];
    get_user_name(id, szName, charsmax(szName));
    
    LoadData(id, szName);
}

public client_disconnect(id)
{
    new szName[32];
    get_user_name(id, szName, charsmax(szName));
    
    SaveData(id, szName);
}

LoadData(id, szName[])
{
    new szData[32];
    
    if (fvault_get_data(szFVaultName, szName, szData, charsmax(szData)))
    {
        g_iPlayedSeconds[id] = str_to_num(szData);
    }
    else
    {
        g_iPlayedSeconds[id] = 0;
    }
}

SaveData(id, szName[])
{
    new szData[32];
    num_to_str(g_iPlayedSeconds[id], szData, charsmax(szData));
    
    fvault_set_data(szFVaultName, szName, szData);
}

GetTimeFormat(iSeconds, szFormat[32])
{
    new iHours = iSeconds / 3600;
    formatex(szFormat, charsmax(szFormat), "%s%i", (iHours < 10) ? "0" : "", iHours);
    
    new iMinutes = iSeconds % 3600 / 60;
    format(szFormat, charsmax(szFormat), "%s:%s%i", szFormat, (iMinutes < 10) ? "0" : "", iMinutes);
    
    iSeconds = iSeconds % 3600 % 60;
    format(szFormat, charsmax(szFormat), "%s:%s%i", szFormat, (iSeconds < 10) ? "0" : "", iSeconds);
} 

Try

[cgozzie]

Благодаря сега ще го тествам.

[cgozzie]

Сичко работи запазва времето само ако може да е статично а не да премигва щот дразни така..

[TheRedShoko]

Съобщението е статично, премигването се дължи на някой друг плъгин, който му пречи. Ако имаш много HUD съобщения по екрана - това е причината за премигването.

[cgozzie]

Имам статичен армуранк най долу в средата и 1 горе пак в средата трябва да ги спра 1 по 1 да разбера от кой може да е и да видим дали може да се направи нещо.Ще пиша след малко да кажа от кой е...