vip plugin

[Buzdrev]

Здравейте, можете ли на този код да ми добавите няколко реда, така че при спаун освен тези неща да ми дава и deagle

Код за потвърждение: Избери целия код

#include < amxmodx > 
#include < amxmisc >
#include < fakemeta > 
#include < hamsandwich > 
#include < cstrike > 
#include < fun > 

#pragma semicolon 1 

#define PLUGIN "Admins are VIPs" 
#define VERSION "0.0.1" 

#define MONEY_KILL		450
#define MONEY_HS		900

#define MAX_MONEY_IN_GAME	16000

public plugin_init() 
{ 
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" ); 
    RegisterHam(Ham_Spawn, "player", "OnCBasePlayer_Spawn_Post", true); 
    register_event( "DeathMsg", "evDeath", "a" );
} 

public evDeath( )
{
	new attacker = read_data( 1 );
	
	if( attacker == read_data( 2 ) || !is_user_alive( attacker ) || is_user_connected( attacker ) || cs_get_user_money( attacker ) >= MAX_MONEY_IN_GAME ) return PLUGIN_HANDLED;
	
	if( read_data( 3 ) ) 
	{
		if( cs_get_user_money( attacker ) <= MAX_MONEY_IN_GAME - MONEY_HS )
		{
			cs_set_user_money( attacker, cs_get_user_money( attacker ) + MONEY_HS );
		}
	}
	else 
	{
		if( cs_get_user_money( attacker ) <= MAX_MONEY_IN_GAME - MONEY_KILL )
		{
			cs_set_user_money( attacker, cs_get_user_money( attacker ) + MONEY_KILL );
		}
	}
	
	return PLUGIN_CONTINUE;
} 

public OnCBasePlayer_Spawn_Post( id ) 
{ 
    if( is_user_alive( id ) && get_user_flags( id ) & ADMIN_LEVEL_E ) 
    { 	
        cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM); 
        new weapons = pev(id, pev_weapons); 
        if( ~weapons & CSW_FLASHBANG ) 
        { 
            give_item(id, "weapon_flashbang"); 
        } 
        cs_set_user_bpammo(id, CSW_FLASHBANG, 2); 
        if( ~weapons & CSW_HEGRENADE ) 
        { 
            give_item(id, "weapon_hegrenade"); 
        } 
	if( ~weapons & CSW_SMOKEGRENADE ) 
        { 
            give_item(id, "weapon_smokegrenade"); 
        } 
        if(is_user_alive(id) && get_user_flags(id) & ADMIN_LEVEL_E && cs_get_user_team(id) == CS_TEAM_CT) 
        {
		cs_set_user_defuse(id, 1);
        }
    } 
} 

[Extreme]

Код за потвърждение: Избери целия код

#include < amxmodx > 
#include < fakemeta > 
#include < hamsandwich > 
#include < cstrike > 
#include < fun > 

#pragma semicolon 1 

#define PLUGIN "Admins are VIPs" 
#define VERSION "0.0.1" 

new const m_rgpPlayerItems_CBasePlayer[6] = {367,368,...}; 
const m_pActiveItem = 373; 

public plugin_init() 
{ 
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" ); 
    RegisterHam(Ham_Spawn, "player", "OnCBasePlayer_Spawn_Post", true); 
} 

public OnCBasePlayer_Spawn_Post( id ) 
{ 
    if( is_user_alive( id ) && get_user_flags( id ) & ADMIN_IMMUNITY ) 
    { 
        cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM); 
        new weapons = pev(id, pev_weapons); 
        if( ~weapons & CSW_FLASHBANG ) 
        { 
            give_item(id, "weapon_flashbang"); 
        } 
        cs_set_user_bpammo(id, CSW_FLASHBANG, 2); 
        if( ~weapons & CSW_HEGRENADE ) 
        { 
            give_item(id, "weapon_hegrenade"); 
        } 

        new gun = get_pdata_cbase(id, m_rgpPlayerItems_CBasePlayer[2]); 
        if( gun > 0 ) 
        { 
            new iId = cs_get_weapon_id(gun); 
            if( iId == CSW_DEAGLE ) 
            { 
                cs_set_weapon_ammo(gun, 7); 
            } 
            else 
            { 
                ham_strip_user_weaponent(id, gun, iId, true); 
                give_item( id, "weapon_deagle" ); 
            } 
        } 

        cs_set_user_bpammo( id, CSW_DEAGLE, 35 ); 
    } 
} 

ham_strip_user_weaponent(id, weaponEnt, iId=0, bool:bSwitchIfActive = true) 
{ 
    if( bSwitchIfActive && get_pdata_cbase(id, m_pActiveItem) == weaponEnt ) 
    { 
        ExecuteHamB(Ham_Weapon_RetireWeapon, weaponEnt); 
    } 

    if( ExecuteHamB(Ham_RemovePlayerItem, id, weaponEnt) ) 
    { 
        if( !iId ) 
        { 
            iId = cs_get_weapon_id(weaponEnt); 
        } 
        user_has_weapon(id, iId, 0); 
        ExecuteHamB(Ham_Item_Kill, weaponEnt); 
        return 1; 
    } 
    return 0; 
}  

[Buzdrev]

Благодаря, локвайте.