VIP PLUGIN

[HeatoN]

Здравейте, трябва ми плъгин за випове който има флаг (b) да има 30% повече спийд и Double Jump трябва ми за awp сървър ако някой има и друга идея за вип екстра може да я добави

[Midnight1337]

Код за потвърждение: Избери целия код

#pragma semicolon 1

#include <amxmodx>
#include <reapi>

#define VIP_ACCESS      ADMIN_RESERVATION    // VIP ACCESS
#define SPEED			300.0               // Player speed adjust if needed

#define is_user_vip(%1)         (get_user_flags(%1) & VIP_ACCESS)

new g_JumpCount[MAX_CLIENTS];

public plugin_init() {
    register_plugin("VIP", "0.0.1", "mIDnight");

    RegisterHookChain(RG_CBasePlayer_Jump, "@CBasePlayer_Jump_Pre", .post = false);
    RegisterHookChain(RG_CBasePlayer_ResetMaxSpeed, "@CBasePlayer_ResetMaxSpeed_Post", .post =true);
}

@CBasePlayer_Jump_Pre(const pPlayer) {
    if (!is_user_vip(pPlayer) || (get_entvar(pPlayer, var_flags) & FL_WATERJUMP) || (get_entvar(pPlayer, var_waterlevel) >= 2) || !(get_member(pPlayer, m_afButtonPressed) & IN_JUMP)) {
        return;
    }

    if (get_entvar(pPlayer, var_flags) & FL_ONGROUND) {
        g_JumpCount[pPlayer] = 0;
    } else {
        if (Float:get_member(pPlayer, m_flFallVelocity) < 500.0 && !g_JumpCount[pPlayer]++) {
            new Float:velocity[3];
            get_entvar(pPlayer, var_velocity, velocity);
            velocity[2] = 268.328157;
            set_entvar(pPlayer, var_velocity, velocity);
        }
    }
}

@CBasePlayer_ResetMaxSpeed_Post(const pPlayer){
	if (is_user_vip(pPlayer))	set_entvar(pPlayer, var_maxspeed, SPEED);
}

[HeatoN]

thank you bro