Проблем с плъгин Golden AWP

Въпроси и проблеми свързани с AMXModX.
Отговори
Потребителски аватар

Автор на темата
metamod CS-DOWN
Потребител
Потребител
Мнения: 63
Регистриран: 07 апр 2018, 11:06
Се отблагодари: 4 пъти
Години: 26
Контакти:

Проблем с плъгин Golden AWP

Мнение от metamod CS-DOWN » 12 окт 2019, 18:41

Имам проблем със този плъгин

Код: Избери всички

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define GOLDEN_AWP_V_MODEL "models/v_awp.mdl"
#define GOLDEN_AWP_P_MODEL "models/p_awp.mdl"
#define GOLDEN_AWP_DMG_MULTIPLIER 2
#define GOLDEN_AWP_PRICE 16000
#define GOLDEN_AWP_GLOW_COLOR 255, 255, 0
#define GOLDEN_AWP_GLOW_ALPHA 40

new bool:g_bHasGolden[33]

public plugin_init()
{
	register_plugin("Golden AWP", "1.0", "OciXCrom")
	register_clcmd("say /gawp", "Cmd_BuyGolden")
	register_clcmd("say_team /gawp", "Cmd_BuyGolden")
	register_event("CurWeapon", "OnSelectAWP", "be", "1=1", "2=18")
	register_event("DeathMsg", "OnPlayerKilled", "a")
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
	CC_SetPrefix("&x04[Golden AWP]")
}

public plugin_precache()
{
	#if defined GOLDEN_AWP_V_MODEL
	precache_model(GOLDEN_AWP_V_MODEL)
	#endif
	
	#if defined GOLDEN_AWP_P_MODEL
	precache_model(GOLDEN_AWP_P_MODEL)
	#endif
}

public client_putinserver(id)
	g_bHasGolden[id] = false

public Cmd_BuyGolden(id)
{
	if(g_bHasGolden[id])
		CC_SendMessage(id, "You already have a &x04Golden AWP&x01.")
	else
	{
		new iMoney = cs_get_user_money(id)
		
		if(iMoney >= GOLDEN_AWP_PRICE)
		{
			g_bHasGolden[id] = true
			cs_set_user_money(id, iMoney - GOLDEN_AWP_PRICE)
			CC_SendMessage(id, "You bought a &x03Golden AWP &x01for &x04%i$", GOLDEN_AWP_PRICE)
			set_user_rendering(id, kRenderFxGlowShell, GOLDEN_AWP_GLOW_COLOR, kRenderTransAlpha, GOLDEN_AWP_GLOW_ALPHA)
			give_item(id, "weapon_awp")
			cs_set_user_bpammo(id, CSW_AWP, 30)
			
			if(get_user_weapon(id) == CSW_AWP)
				OnSelectAWP(id)
		}
		else CC_SendMessage(id, "You need &x04%i$ &x01to purchase this.", GOLDEN_AWP_PRICE)
	}
	
	return PLUGIN_HANDLED
}

public OnPlayerKilled()
{
	new iVictim = read_data(2)
	
	if(!is_user_connected(iVictim))
		return

	if(g_bHasGolden[iVictim])
	{
		g_bHasGolden[iVictim] = false
		set_user_rendering(iVictim)
	}
}

public OnSelectAWP(id)
{
	#if defined GOLDEN_AWP_V_MODEL
	set_pev(id, pev_viewmodel2, GOLDEN_AWP_V_MODEL)
	#endif
	
	#if defined GOLDEN_AWP_P_MODEL
	set_pev(id, pev_weaponmodel2, GOLDEN_AWP_P_MODEL)
	#endif
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage)
{
    if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bHasGolden[iAttacker])
        SetHamParamFloat(4, fDamage * GOLDEN_AWP_DMG_MULTIPLIER)
}
Когато си купиш АВП-то не свети и също така във ЦСДМ менюто се бъркат двата модела който са за обикновенното и това златното.Има ли някакъв начин да се оправи,също така възможно ли е да се направи със златни патрони когато стреляш и да изписва ХУД съобщение когато някой го притежава.
CS-DOWN.bg # RespawN IP: 93.123.18.42:27015

Отговори

Върни се в “Поддръжка / Помощ”

Кой е на линия

Потребители, разглеждащи този форум: Няма регистрирани потребители и 0 госта