/spec,/back плугина се бъгна

Въпроси и проблеми свързани с AMXModX.
Потребителски аватар

OciXCrom TM
Администратор
Администратор
Мнения: 5564
Регистриран: 06 окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 102 пъти
Получена благодарност: 648 пъти
Години: 22
Контакти:

/spec,/back плугина се бъгна

Мнение от OciXCrom TM » 07 ное 2019, 23:27

Никакъв. Оставяш квара празен - ""

Потребителски аватар

impossible
Потребител
Потребител
Мнения: 54
Регистриран: 15 юни 2019, 12:41
Се отблагодари: 6 пъти
Получена благодарност: 3 пъти

/spec,/back плугина се бъгна

Мнение от impossible » 09 ное 2019, 11:26

Как може да се настрои като напишеш /spec просто да те препраща ,а не да показва че имаш умирания всеки път като отидеш spec взима фраг нещо като самоубийство го отчита

Потребителски аватар

OciXCrom TM
Администратор
Администратор
Мнения: 5564
Регистриран: 06 окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 102 пъти
Получена благодарност: 648 пъти
Години: 22
Контакти:

/spec,/back плугина се бъгна

Мнение от OciXCrom TM » 09 ное 2019, 14:23

impossible написа:
09 ное 2019, 11:26
Как може да се настрои като напишеш /spec просто да те препраща ,а не да показва че имаш умирания всеки път като отидеш spec взима фраг нещо като самоубийство го отчита
Поясни за кой от двата плъгина се отнася въпросът...

Потребителски аватар

Автор на темата
digitalbg
Потребител
Потребител
Мнения: 52
Регистриран: 07 май 2019, 13:13
Местоположение: Добрич
Получена благодарност: 2 пъти
Години: 26

/spec,/back плугина се бъгна

Мнение от digitalbg » 09 ное 2019, 15:16

Така .... твоите думи Иначе предполагам проблемът е във функцията cs_user_spawn(id) и трябва да се смени с ExecuteHamB(Ham_CS_RoundRespawn, id) + да се добави #include <hamsandwich>.
пак е така ... същото , а за другият плугин като го дам така "" си е все тая.
Извинявай като смених цваровете в сма-то с твоя плугин се получи :) Благодаря ти!!

Потребителски аватар

OciXCrom TM
Администратор
Администратор
Мнения: 5564
Регистриран: 06 окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 102 пъти
Получена благодарност: 648 пъти
Години: 22
Контакти:

/spec,/back плугина се бъгна

Мнение от OciXCrom TM » 09 ное 2019, 15:28

Кварове не се променят от .sma файла, а се добавят в configs/amxx.cfg.

Потребителски аватар

Автор на темата
digitalbg
Потребител
Потребител
Мнения: 52
Регистриран: 07 май 2019, 13:13
Местоположение: Добрич
Получена благодарност: 2 пъти
Години: 26

/spec,/back плугина се бъгна

Мнение от digitalbg » 09 ное 2019, 16:30

Така и направих първият път... но все ми даваше U have no acces май беше ...

Потребителски аватар

impossible
Потребител
Потребител
Мнения: 54
Регистриран: 15 юни 2019, 12:41
Се отблагодари: 6 пъти
Получена благодарност: 3 пъти

/spec,/back плугина се бъгна

Мнение от impossible » 09 ное 2019, 23:54

https://www.amxx-bg.info/viewtopic.php?t=1114 ползвам твоя плъгин но щом напиша /spec ме праща но ми взима фрагове показва ,че съм бил убит но не от играч ,а самия плъгин примерно пиша /spec 3 пъти подред и ми показва deaths -3 мисълта ми е как да се настрои да не взима от фрaговете а просто да те препраща spec без да отчита умирания

Потребителски аватар

OciXCrom TM
Администратор
Администратор
Мнения: 5564
Регистриран: 06 окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 102 пъти
Получена благодарност: 648 пъти
Години: 22
Контакти:

/spec,/back плугина се бъгна

Мнение от OciXCrom TM » 10 ное 2019, 01:02

Това се случва поради бъг от самия АМХХ. Виж така дали има разлика:

Код: Избери всички

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define PLUGIN_VERSION "1.2-test1"

enum _:Cvars
{
	gospec_spec_flag,
	gospec_change_flag,
	gospec_respawn
}

new g_eCvars[Cvars]

new CsTeams:g_iOldTeam[33],
	g_iSpecFlag,
	g_iChangeFlag

public plugin_init()
{
	register_plugin("GoSpec", PLUGIN_VERSION, "OciXCrom")
	register_cvar("@CRXGoSpec", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_dictionary("GoSpec.txt")

	register_clcmd("say /spec", "GoSpec")
	register_clcmd("say /back", "GoBack")
	register_clcmd("say /change", "SwitchTeam")

	g_eCvars[gospec_spec_flag] = register_cvar("gospec_spec_flag", "e")
	g_eCvars[gospec_change_flag] = register_cvar("gospec_change_flag", "e")
	g_eCvars[gospec_respawn] = register_cvar("gospec_respawn", "0")
	CC_SetPrefix("[&x03GoSpec&x01]")
}

public plugin_cfg()
{
	new szFlag[2]
	get_pcvar_string(g_eCvars[gospec_spec_flag], szFlag, charsmax(szFlag))
	g_iSpecFlag = szFlag[0] == EOS ? ADMIN_ALL : read_flags(szFlag)
	get_pcvar_string(g_eCvars[gospec_change_flag], szFlag, charsmax(szFlag))
	g_iChangeFlag = szFlag[0] == EOS ? ADMIN_ALL : read_flags(szFlag)
}

public GoSpec(id)
{
	if(!HasAccess(id, g_iSpecFlag))
		return PLUGIN_HANDLED

	new CsTeams:iTeam = cs_get_user_team(id)

	if(iTeam == CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_ALREADY_SPECTATOR")
	else
	{
		g_iOldTeam[id] = iTeam
		cs_set_user_team(id, CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_NOW_SPECTATOR")

		if(is_user_alive(id))
			SafeKill(id)
	}

	return PLUGIN_HANDLED
}

public GoBack(id)
{
	if(!HasAccess(id, g_iSpecFlag))
		return PLUGIN_HANDLED

	if(cs_get_user_team(id) != CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_NOT_SPECTATOR")
	else
	{
		new iPlayers[32], iCT, iT
		get_players(iPlayers, iCT, "e", "CT")
		get_players(iPlayers, iT, "e", "TERRORIST")

		if(iCT == iT)
		{
			cs_set_user_team(id, g_iOldTeam[id])
			CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_PREVIOUS")
		}
		else
		{
			cs_set_user_team(id, iCT > iT ? CS_TEAM_T : CS_TEAM_CT)
			CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_LESS")
		}

		if(get_pcvar_num(g_eCvars[gospec_respawn]))
			ExecuteHamB(Ham_CS_RoundRespawn, id)
	}

	return PLUGIN_HANDLED
}

public SwitchTeam(id)
{
	if(!HasAccess(id, g_iChangeFlag))
		return PLUGIN_HANDLED

	new CsTeams:iTeam = cs_get_user_team(id)


	if(iTeam == CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_CANT_USE")
	else
	{
		cs_set_user_team(id, cs_get_user_team(id) == CS_TEAM_CT ? CS_TEAM_T : CS_TEAM_CT)
		CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_OPPOSITE")

		if(is_user_alive(id))
		{
			SafeKill(id)

			if(get_pcvar_num(g_eCvars[gospec_respawn]))
				ExecuteHamB(Ham_CS_RoundRespawn, id)
		}
	}

	return PLUGIN_HANDLED
}

SafeKill(id)
{
	new iFrags = get_user_frags(id), iDeaths = cs_get_user_deaths(id)
	user_silentkill(id)
	set_user_frags(id, iFrags)
	cs_set_user_deaths(id, iDeaths)
}

bool:HasAccess(id, iFlag)
{
	if(iFlag == ADMIN_ALL || get_user_flags(id) & iFlag)
		return true
	else
	{
		CC_SendMessage(id, "%L", id, "GOSPEC_NO_ACCESS")
		return false
	}

	#if AMXX_VERSION_NUM < 183
	return false
	#endif
}

Потребителски аватар

impossible
Потребител
Потребител
Мнения: 54
Регистриран: 15 юни 2019, 12:41
Се отблагодари: 6 пъти
Получена благодарност: 3 пъти

/spec,/back плугина се бъгна

Мнение от impossible » 10 ное 2019, 09:57

да така работи!

Потребителски аватар

OciXCrom TM
Администратор
Администратор
Мнения: 5564
Регистриран: 06 окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 102 пъти
Получена благодарност: 648 пъти
Години: 22
Контакти:

/spec,/back плугина се бъгна

Мнение от OciXCrom TM » 10 ное 2019, 14:17

Ще обновя и главния плъгин.

Отговори

Върни се в “Поддръжка / Помощ”

Кой е на линия

Потребители, разглеждащи този форум: Няма регистрирани потребители и 0 госта