Заявка за Basebuilder 6.5 ( Tirant ) магазин

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
Русский Мясник
Извън линия
Потребител
Потребител
Мнения: 36
Регистриран на: 14 Сеп 2019, 19:36
Се отблагодари: 7 пъти
Получена благодарност: 2 пъти

Заявка за Basebuilder 6.5 ( Tirant ) магазин

Мнение от Русский Мясник » 27 Ное 2019, 17:58

Здравейте, нуждая се от магазин, тъй като не успях да намеря точно това, което ми трябва.
Трябва ми магазин с пари и да съдържа следните артикули:

Counter-Terrorists:
1. +50 HP [5000$] - дава 50 HP на купувача
2. No Recoil [7000$]- премахва отката на оръжията на купувача
3. Grenade Pack [3000$] - дава 1 HE и 1 FN на купувача
4. Super Knife [10000$] - x3 щета на ножа + променя модела
5. Strong AK47 [15000$] - x2 щета + променя модела + zoom
6. Strong M4A1 [15000$] - x2 щета + променя модела + zoom
7. Strong AWP [15000$] - x2 щета + променя модела

Terrorists:
1. +1000 HP - дава 1000 HP на купувача
2. Claws - x2 щета + променя модела

Много ще бъда благодарен! :lol:
Basebuilder 6.5 CSO Mod -- 70%
Massive Public -- 90%

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за Basebuilder 6.5 ( Tirant ) магазин

Мнение от OciXCrom » 27 Ное 2019, 21:17


Аватар
Русский Мясник
Извън линия
Потребител
Потребител
Мнения: 36
Регистриран на: 14 Сеп 2019, 19:36
Се отблагодари: 7 пъти
Получена благодарност: 2 пъти

Заявка за Basebuilder 6.5 ( Tirant ) магазин

Мнение от Русский Мясник » 04 Дек 2019, 21:50

Благодаря ти! Перфектно! А как да направя за различните отбори съответно Mega Knife-а да е с различни модели и може ли да направиш съб-плъгин за HP?
Basebuilder 6.5 CSO Mod -- 70%
Massive Public -- 90%

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Заявка за Basebuilder 6.5 ( Tirant ) магазин

Мнение от OciXCrom » 09 Дек 2019, 14:19

Ножът (настрой си моделите):

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <customshop>
#include <fakemeta>
#include <hamsandwich>

#if !defined m_pPlayer
	#define m_pPlayer 41
#endif

#define PLUGIN_VERSION "1.0.2+teams"

#define V_MODEL_CT "models/custom_shop/v_dagger.mdl"
#define P_MODEL_CT "models/custom_shop/p_dagger.mdl"

#define V_MODEL_T "models/custom_shop/v_dagger.mdl"
#define P_MODEL_T "models/custom_shop/p_dagger.mdl"

additem ITEM_MEGA_KNIFE
new g_bHasItem[33], g_szDamage[16]

public plugin_init()
{
	register_plugin("CSHOP: Mega Knife", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CSHOPMegaKnife", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	RegisterHam(Ham_Item_Deploy, "weapon_knife", "OnSelectKnife", 1)
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
	cshop_get_string(ITEM_MEGA_KNIFE, "Amount", g_szDamage, charsmax(g_szDamage))
}

public plugin_precache()
{
	ITEM_MEGA_KNIFE = cshop_register_item("megaknife", "Mega Knife", 8000)
	cshop_set_string(ITEM_MEGA_KNIFE, "Amount", "+100%")

	#if defined V_MODEL_CT
	precache_model(V_MODEL_CT)
	#endif

	#if defined P_MODEL_CT
	precache_model(P_MODEL_CT)
	#endif

	#if defined V_MODEL_T
	precache_model(V_MODEL_T)
	#endif

	#if defined P_MODEL_T
	precache_model(P_MODEL_T)
	#endif
}

public cshop_item_selected(id, iItem)
{
	if(iItem == ITEM_MEGA_KNIFE)
	{
		g_bHasItem[id] = true

		if(get_user_weapon(id) == CSW_KNIFE)
			RefreshKnifeModel(id)
	}
}

public cshop_item_removed(id, iItem)
{
   if(iItem == ITEM_MEGA_KNIFE)
	  g_bHasItem[id] = false
}

public client_putinserver(id)
	g_bHasItem[id] = false

public OnSelectKnife(iEnt)
{
	new id = get_pdata_cbase(iEnt, m_pPlayer, 4)

	if(g_bHasItem[id] && is_user_connected(id))
		RefreshKnifeModel(id)
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bHasItem[iAttacker])
		SetHamParamFloat(4, math_add_f(fDamage, g_szDamage))
}

RefreshKnifeModel(const id)
{
	switch(cs_get_user_team(id))
	{
		case CS_TEAM_CT:
		{
			#if defined V_MODEL_CT
			set_pev(id, pev_viewmodel2, V_MODEL_CT)
			#endif

			#if defined P_MODEL_CT
			set_pev(id, pev_weaponmodel2, P_MODEL_CT)
			#endif
		}
		case CS_TEAM_T:
		{
			#if defined V_MODEL_T
			set_pev(id, pev_viewmodel2, V_MODEL_T)
			#endif

			#if defined P_MODEL_T
			set_pev(id, pev_weaponmodel2, P_MODEL_T)
			#endif
		}
	}
}

Float:math_add_f(Float:fNum, const szMath[])
{
	static szNewMath[16], Float:fMath, bool:bPercent, cOperator

	copy(szNewMath, charsmax(szNewMath), szMath)
	bPercent = szNewMath[strlen(szNewMath) - 1] == '%'
	cOperator = szNewMath[0]

	if(!isdigit(szNewMath[0]))
		szNewMath[0] = ' '

	if(bPercent)
		replace(szNewMath, charsmax(szNewMath), "%", "")

	trim(szNewMath)
	fMath = str_to_float(szNewMath)

	if(bPercent)
		fMath *= fNum / 100

	switch(cOperator)
	{
		case '+': fNum += fMath
		case '-': fNum -= fMath
		case '/': fNum /= fMath
		case '*': fNum *= fMath
		default: fNum = fMath
	}

	return fNum
}
HP:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <customshop>
#include <fun>

new const PLUGIN_VERSION[] = "1.0"

additem ITEM_HEALTH
new g_iAmount

public plugin_init()
{
	register_plugin("CSHOP: Health", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CSHOPHealth", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	g_iAmount = cshop_get_int(ITEM_HEALTH, "Amount")
}

public plugin_precache()
{
	ITEM_HEALTH = cshop_register_item("healthsub", "Health", 3000)
	cshop_set_int(ITEM_HEALTH, "Amount", 100)
}

public cshop_item_selected(id, iItem)
{
	if(iItem == ITEM_HEALTH)
	{
		set_user_health(id, get_user_health(id) + g_iAmount)
	}
}

Публикувай отговор
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 12 госта